-type action() ::
          postpone |
          {postpone, Postpone :: postpone()} |
          {next_event, EventType :: event_type(), EventContent :: event_content()} |
          {change_callback_module, NewModule :: module()} |
          {push_callback_module, NewModule :: module()} |
          pop_callback_module |
          enter_action().

Actions for a state transition, or when starting the server.

These transition actions can be invoked by returning them from the state callback when it is called with an event, from Module:init/1 or by passing them to enter_loop/4,5,6. They are not allowed from state enter calls.

Actions are executed in the containing list order.

Actions that set transition options override any previous of the same type, so the last in the containing list wins. For example, the last postpone/0 overrides any previous postpone/0 in the list.

• {postpone, Value} - Sets the transition_option() postpone/0 for this state transition. This action is ignored when returned from Module:init/1 or passed to enter_loop/4,5,6, as there is no event to postpone in those cases.

  postpone is equivalent to {postpone, true}.

• {next_event, EventType, EventContent} - This action does not set any transition_option() but instead stores the specified EventType and EventContent for insertion after all actions have been executed.

  The stored events are inserted in the queue as the next to process before any already queued events. The order of these stored events is preserved, so the first next_event in the containing list becomes the first to process.

  An event of type internal should be used when you want to reliably distinguish an event inserted this way from any external event.

• {change_callback_module, NewModule} - Changes the callback module to NewModule which will be used when calling all subsequent state callbacks.
  Since OTP 22.3.

  The gen_statem engine will find out the callback mode of NewModule by calling NewModule:callback_mode/0 before the next state callback.

  Changing the callback module does not affect the state transition in any way, it only changes which module that handles the events. Be aware that all relevant callback functions in NewModule such as the state callback, NewModule:code_change/4, NewModule:format_status/1 and NewModule:terminate/3 must be able to handle the state and data from the old module.

• {push_callback_module, NewModule} - Pushes the current callback module to the top of an internal stack of callback modules, and changes the callback module to NewModule. Otherwise like {change_callback_module, NewModule} above.
  Since OTP 22.3.

• pop_callback_module - Pops the top module from the internal stack of callback modules and changes the callback module to be the popped module. If the stack is empty the server fails. Otherwise like {change_callback_module, NewModule} above.
  Since OTP 22.3.

-type callback_mode() :: state_functions | handle_event_function.

One function per state or one common event handler.

The callback mode is selected with the return value from Module:callback_mode/0:

• state_functions - The state must be of type state_name/0 and one callback function per state, that is, Module:StateName/3, is used.

• handle_event_function - The state can be any term and the callback function Module:handle_event/4 is used for all states.

The function Module:callback_mode/0 is called when starting the gen_statem, after code change and after changing the callback module with any of the actions change_callback_module, push_callback_module, or pop_callback_module. The result is cached for subsequent calls to state callbacks.

-type callback_mode_result() :: callback_mode() | [callback_mode() | state_enter()].

Return value from Module:callback_mode/0.

This is the return type from Module:callback_mode/0 which selects callback mode and whether to do state enter calls, or not.

-type data() :: term().

Generic state data for the server.

A term in which the state machine implementation is to store any server data it needs. The difference between this and the state/0 itself is that a change in this data does not cause postponed events to be retried. Hence, if a change in this data would change the set of events that are handled, then that data item should be part of the state/0 instead.

-type enter_action() ::
          hibernate | {hibernate, Hibernate :: hibernate()} | timeout_action() | reply_action().

Actions for any callback: hibernate, time-outs or replies.

These transition actions are allowed when a action/0 is allowed, and also from a state enter call, and can be invoked by returning them from the state callback, from Module:init/1 or by passing them to enter_loop/4,5,6.

Actions are executed in the containing list order.

Actions that set transition options override any previous of the same type, so the last in the containing list wins. For example, the last event_timeout/0 overrides any previous event_timeout/0 in the list.

• {hibernate, Value} - Sets the transition_option/0 hibernate/0 for this state transition.

  hibernate is equivalent to {hibernate, true}.

-type enter_loop_opt() ::
          {hibernate_after, HibernateAfterTimeout :: timeout()} | {debug, Dbgs :: [sys:debug_option()]}.

Server start options for the enter_loop/4,5,6, start/3,4, start_link/3,4, and start_monitor/3,4, functions.

See start_link/4.

-type event_content() :: term().

Event payload from the event's origin, delivered to the state callback.

See event_type that describes the origins of the different event types, which is also where the event's content comes from.

-type event_handler_result(StateType, DataType) ::
          {next_state, NextState :: StateType, NewData :: DataType} |
          {next_state, NextState :: StateType, NewData :: DataType, Actions :: [action()] | action()} |
          state_callback_result(action(), DataType).

Return value from a state callback after handling an event.

StateType is state_name/0 if callback mode is state_functions, or state/0 if callback mode is handle_event_function.

• {next_state, NextState, NewData [, Actions]} - The gen_statem does a state transition to NextState (which may be the same as the current state), sets NewData as the current server data/0, and executes all Actions. If NextState =/= CurrentState the state transition is a state change.

-type event_timeout() :: Time :: timeout() | integer().

How long to wait for an event.

Starts a timer set by timeout_action/0 Time, or {timeout, Time, EventContent [, Options]}.

When the timer expires an event of event_type/0 timeout will be generated. See erlang:start_timer/4 for how Time and Options are interpreted. Future erlang:start_timer/4 Options will not necessarily be supported.

Any event that arrives cancels this time-out. Note that a retried or inserted event counts as arrived. So does a state time-out zero event, if it was generated before this time-out is requested.

If Time is infinity, no timer is started, as it never would expire anyway.

If Time is relative and 0 no timer is actually started, instead the the time-out event is enqueued to ensure that it gets processed before any not yet received external event, but after already queued events.

Note that it is not possible nor needed to cancel this time-out, as it is cancelled automatically by any other event, meaning that whenever a callback is invoked that may want to cancel this time-out, the timer is already cancelled or expired.

The timer EventContent can be updated with the {timeout, update, NewEventContent} action without affecting the time of expiry.

-type event_type() :: external_event_type() | timeout_event_type() | internal.

All event types: external, time-out, or internal.

internal events can only be generated by the state machine itself through the transition action next_event.

-type external_event_type() :: {call, From :: from()} | cast | info.

Event from a call, cast, or regular process message; "info".

Type {call, From} originates from the API functions call/2,3 or send_request/2. The event contains From, which is whom to reply to by a reply_action/0 or reply/2,3 call.

Type cast originates from the API function cast/2.

Type info originates from regular process messages sent to the gen_statem process.

-type format_status() ::
          #{state => state(),
            data => data(),
            reason => term(),
            queue => [{event_type(), event_content()}],
            postponed => [{event_type(), event_content()}],
            timeouts => [{timeout_event_type(), event_content()}],
            log => [sys:system_event()]}.

A map that describes the server's status.

The keys are:

• state - The current state.
• data - The state data.
• reason - The reason that caused the process to terminate.
• queue - The event queue.
• postponed - The queue of postponed events.
• timeouts - The active time-outs.
• log - The sys log of the server.

New associations may be added to the status map without prior notice.

-type from() :: {To :: pid(), Tag :: reply_tag()}.

A call event's reply destination.

Destination to use when replying through, for example, the action {reply, From, Reply} to a process that has called the gen_statem server using call/2,3.

-type generic_timeout() :: Time :: timeout() | integer().

How long to wait for a named time-out event.

Starts a timer set by timeout_action/0 {{timeout, Name}, Time, EventContent [, Options]}.

When the timer expires an event of event_type/0 {timeout, Name} will be generated. See erlang:start_timer/4 for how Time and Options are interpreted. Future erlang:start_timer/4 Options will not necessarily be supported.

If Time is infinity, no timer is started, as it never would expire anyway.

If Time is relative and 0 no timer is actually started, instead the time-out event is enqueued to ensure that it gets processed before any not yet received external event.

Setting a timer with the same Name while it is running will restart it with the new time-out value. Therefore it is possible to cancel a specific time-out by setting it to infinity. It can also be cancelled more explicitly with the {{timeout, Name}, cancel} action.

The timer EventContent can be updated with the {{timeout, Name}, update, NewEventContent} action without affecting the time of expiry.

-type hibernate() :: boolean().

Hibernate the server process.

If true, hibernates the gen_statem by calling proc_lib:hibernate/3 before going into receive to wait for a new external event.

There is also a server start option {hibernate_after, Timeout} for automatic hibernation.

Note

If there are enqueued events to process when hibernation is requested, this is optimized by not hibernating but instead calling erlang:garbage_collect/0 to simulate, in a more effective way, that the gen_statem entered hibernation and immediately got awakened by an enqueued event.

-type init_result(StateType, DataType) ::
          {ok, State :: StateType, Data :: DataType} |
          {ok, State :: StateType, Data :: DataType, Actions :: [action()] | action()} |
          ignore |
          {stop, Reason :: term()} |
          {error, Reason :: term()}.

The return value from Module:init/1.

For a succesful initialization, State is the initial state/0, and Data the initial server data/0 of the gen_statem.

The Actions are executed when entering the first state just as for a state callback, except that the action postpone is forced to false since there is no event to postpone.

For an unsuccesful initialization, {stop, Reason}, {error, Reason}, or ignore should be used; see start_link/3,4.

{error, Reason} has been allowed since OTP 26.0.

The {ok, ...} tuples have existed since OTP 19.1, before that they were not ok tagged. This was before gen_statem replaced gen_fsm in OTP 20.0.

-type postpone() :: boolean().

Postpone an event to handle it later.

If true, postpones the current event. After a state change (NextState =/= State), it is retried.

-type reply_action() :: {reply, From :: from(), Reply :: term()}.

Reply to a call/2,3.

This transition action can be invoked by returning it from the state callback, from Module:init/1 or by passing it to enter_loop/4,5,6.

It does not set any transition_option() but instead replies to a caller waiting for a reply in call/3. From must be the term from argument {call, From} in a call to a state callback.

Note that using this action from Module:init/1 or enter_loop/4,5,6 would be weird on the border of witchcraft since there has been no earlier call to a state callback in this server.

-opaque reply_tag()

A handle that associates a reply to the corresponding request.

-opaque request_id()

An opaque request identifier. See send_request/2 for details.

-opaque request_id_collection()

An opaque collection of request identifiers (request_id/0).

Each request identifier can be associated with a label chosen by the user. For more information see reqids_new/0.

-type response_timeout() :: timeout() | {abs, integer()}.

Response time-out for an asynchronous call.

Used to set a time limit on how long to wait for a response using either receive_response/2, receive_response/3, wait_response/2, or wait_response/3. The time unit used is millisecond.

Currently valid values:

• 0..4294967295 - Time-out relative to current time in milliseconds.

• infinity - Infinite time-out. That is, the operation will never time out.

• {abs, Timeout} - An absolute Erlang monotonic time time-out in milliseconds. That is, the operation will time out when erlang:monotonic_time(millisecond) returns a value larger than or equal to Timeout. Timeout is not allowed to identify a time further into the future than 4294967295 milliseconds. Specifying the time-out using an absolute value is especially handy when you have a deadline for responses corresponding to a complete collection of requests (request_id_collection/0), since you do not have to recalculate the relative time until the deadline over and over again.

-type server_name() ::
          {local, atom()} | {global, GlobalName :: term()} | {via, RegMod :: module(), Name :: term()}.

Server name specification: local, global, or via registered.

Name specification to use when starting a gen_statem server. See start_link/3 and server_ref/0 below.

-type server_ref() ::
          pid() |
          (LocalName :: atom()) |
          {Name :: atom(), Node :: atom()} |
          {global, GlobalName :: term()} |
          {via, RegMod :: module(), ViaName :: term()}.

Server specification: pid/0 or registered server_name/0.

To be used in call/2,3 to specify the server.

It can be:

• pid() | LocalName - The gen_statem is locally registered.

• {Name, Node} - The gen_statem is locally registered on another node.

• {global, GlobalName} - The gen_statem is globally registered in global.

• {via, RegMod, ViaName} - The gen_statem is registered in an alternative process registry. The registry callback module RegMod is to export functions register_name/2, unregister_name/1, whereis_name/1, and send/2, which are to behave like the corresponding functions in global. Thus, {via, global, GlobalName} is the same as {global, GlobalName}.

-type start_mon_ret() :: {ok, {pid(), reference()}} | ignore | {error, term()}.

Return value from the start_monitor/3,4 functions.

As for start_link/4 but a succesful return wraps the process ID and the monitor reference in a {ok, {pid(),reference()}} tuple.

-type start_opt() ::
          {timeout, Time :: timeout()} | {spawn_opt, [proc_lib:start_spawn_option()]} | enter_loop_opt().

Server start options for the start/3,4, start_link/3,4, and start_monitor/3,4 functions.

See start_link/4.

-type start_ret() :: {ok, pid()} | ignore | {error, term()}.

Return value from the start/3,4 and start_link/3,4 functions.

See start_link/4.

-type state() :: state_name() | term().

State name or state term.

If the callback mode is handle_event_function, the state can be any term. After a state change (NextState =/= State), all postponed events are retried.

Comparing two states for strict equality is assumed to be a fast operation, since for every state transition the gen_statem engine has to deduce if it is a state change.

Note

The smaller the state term, in general, the faster the comparison.

Note that if the "same" state term is returned for a state transition (or a return action without a NextState field is used), the comparison for equality is always fast because that can be seen from the term handle.

But if a newly constructed state term is returned, both the old and the new state terms will have to be traversed until an inequality is found, or until both terms have been fully traversed.

So it is possible to use large state terms that are fast to compare, but very easy to accidentally mess up. Using small state terms is the safe choice.

-type state_callback_result(ActionType, DataType) ::
          {keep_state, NewData :: DataType} |
          {keep_state, NewData :: DataType, Actions :: [ActionType] | ActionType} |
          keep_state_and_data |
          {keep_state_and_data, Actions :: [ActionType] | ActionType} |
          {repeat_state, NewData :: DataType} |
          {repeat_state, NewData :: DataType, Actions :: [ActionType] | ActionType} |
          repeat_state_and_data |
          {repeat_state_and_data, Actions :: [ActionType] | ActionType} |
          stop |
          {stop, Reason :: term()} |
          {stop, Reason :: term(), NewData :: DataType} |
          {stop_and_reply, Reason :: term(), Replies :: [reply_action()] | reply_action()} |
          {stop_and_reply,
           Reason :: term(),
           Replies :: [reply_action()] | reply_action(),
           NewData :: DataType}.

Return value from any state callback.

ActionType is enter_action/0 if the state callback was called with a state enter call, and action/0 if the state callback was called with an event.

• {keep_state, NewData [, Actions]} - The same as {next_state, CurrentState, NewData [, Actions]}.

• keep_state_and_data | {keep_state_and_data, Actions} - The same as {keep_state, CurrentData [, Actions]}.

• {repeat_state, NewData [, Actions]} - If the gen_statem runs with state enter calls, the state enter call is repeated, see type transition_option/0. Other than that {repeat_state, NewData [, Actions]} is the same as {keep_state, NewData [, Actions]}.

• repeat_state_and_data | {repeat_state_and_data, Actions} - The same as {repeat_state, CurrentData [, Actions]}.

• {stop, Reason [, NewData]} - Terminates the gen_statem by calling Module:terminate/3 with Reason and NewData, if specified. An exit signal with this reason is sent to linked processes and ports.

• stop - The same as {stop, normal}.

• {stop_and_reply, Reason, Replies [, NewData]} - Sends all Replies, then terminates the gen_statem like with {stop, Reason [, NewData]}.

All these terms are tuples or atoms and will be so in all future versions of gen_statem.

-type state_enter() :: state_enter.

Callback mode modifier for state enter calls: the atom state_enter.

Both callback modes can use state enter calls, and this is selected by adding this state_enter flag to the callback mode return value from Module:callback_mode/0.

If Module:callback_mode/0 returns a list containing state_enter, the gen_statem engine will, at every state change, that is; NextState =/= CurrentState, call the state callback with arguments (enter, OldState, Data) or (enter, OldState, State, Data), depending on the callback mode.

This may look like an event but is really a call performed after the previous state callback returned, and before any event is delivered to the new state callback. See Module:StateName/3 and Module:handle_event/4. A state enter call may be repeated without doing a state change by returning a repeat_state or repeat_state_and_data action from the state callback.

If Module:callback_mode/0 does not return a list containing state_enter, no state enter calls are done.

If Module:code_change/4 should transform the state, it is regarded as a state rename and not a state change, which will not cause a state enter call.

Note that a state enter call will be done right before entering the initial state, which may be seen as a state change from no state to the initial state. In this case OldState =:= State, which cannot happen for a subsequent state change, but will happen when repeating the state enter call.

-type state_enter_result(State, DataType) ::
          {next_state, State, NewData :: DataType} |
          {next_state, State, NewData :: DataType, Actions :: [enter_action()] | enter_action()} |
          state_callback_result(enter_action(), DataType).

Return value from a state callback after a state enter call.

State is the current state and it cannot be changed since the state callback was called with a state enter call.

• {next_state, State, NewData [, Actions]} - The gen_statem does a state transition to State, which has to be equal to the current state, sets NewData, and executes all Actions.

-type state_name() :: atom().

State name in callback mode state_functions.

If the callback mode is state_functions, the state must be an atom. After a state change (NextState =/= State), all postponed events are retried. Note that the state terminate is not possible to use since it would collide with the optional callback function Module:terminate/3.

-type state_timeout() :: Time :: timeout() | integer().

How long to wait in the current state.

Starts a timer set by timeout_action/0, or {state_timeout, Time, EventContent [, Options]}.

When the timer expires an event of event_type/0 state_timeout will be generated. See erlang:start_timer/4 for how Time and Options are interpreted. Future erlang:start_timer/4 Options will not necessarily be supported.

A state change cancels this timer, if it is running. That is, if the timeout_action/0 that starts this timer is part of a list of action/0s for a state change, NextState =/= CurrentState, the timer runs in the NextState.

If the state machine stays in that new state, now the current state, the timer will run until it expires, which creates the time-out event. If the state machine changes states from the now current state, the timer is cancelled. During the state change from the now current state, a new state time-out may be started for the next NextState.

If the timeout_action/0 that starts this timer is part of a list of action/0s for a state transition that is not a state change, the timer runs in the current state.

If Time is infinity, no timer is started, as it never would expire anyway.

If Time is relative and 0 no timer is actually started, instead the the time-out event is enqueued to ensure that it gets processed before any not yet received external event.

Setting this timer while it is running will restart it with the new time-out value. Therefore it is possible to cancel this time-out by setting it to infinity. It can also be cancelled more explicitly with {state_timeout, cancel}.

The timer EventContent can be updated with the {state_timeout, update, NewEventContent} action without affecting the time of expiry.

-type timeout_action() ::
          (Time :: event_timeout()) |
          {timeout, Time :: event_timeout(), EventContent :: event_content()} |
          {timeout,
           Time :: event_timeout(),
           EventContent :: event_content(),
           Options :: timeout_option() | [timeout_option()]} |
          {{timeout, Name :: term()}, Time :: generic_timeout(), EventContent :: event_content()} |
          {{timeout, Name :: term()},
           Time :: generic_timeout(),
           EventContent :: event_content(),
           Options :: timeout_option() | [timeout_option()]} |
          {state_timeout, Time :: state_timeout(), EventContent :: event_content()} |
          {state_timeout,
           Time :: state_timeout(),
           EventContent :: event_content(),
           Options :: timeout_option() | [timeout_option()]} |
          timeout_cancel_action() |
          timeout_update_action().

Event time-out, generic time-outs or state time-out.

These transition actions can be invoked by returning them from the state callback, from Module:init/1 or by passing them to enter_loop/4,5,6.

These time-out actions sets time-out transition options.

• Time - Short for {timeout, Time, Time}, that is, the time-out message is the time-out time. This form exists to allow the state callback return value {next_state, NextState, NewData, Time} like in gen_fsm.

• {timeout, Time, EventContent [, Options]} - Sets the transition_option/0 event_timeout/0 to Time with EventContent, and time-out options Options.

• {{timeout,Name}, Time, EventContent [, Options]} - Sets the transition_option/0 generic_timeout/0 to Time for time-out Name with EventContent, and time-out options Options.
  Since OTP 20.0.

• {state_timeout, Time, EventContent [, Options]} - Sets the transition_option/0 state_timeout/0 to Time with EventContent, and time-out options Options.
  Since OTP 19.3.

-type timeout_cancel_action() ::
          {timeout, cancel} | {{timeout, Name :: term()}, cancel} | {state_timeout, cancel}.

Clearer way to cancel a time-out than the original setting it to 'infinity'.

It has always been possible to cancel a time-out using timeout_action/0 with Time = infinity, since setting a new time-out time overrides a running timer, and since setting the time to infinity is optimized to not setting a timer (that never will expire). Using this action shows the intention more clearly.

-type timeout_event_type() :: timeout | {timeout, Name :: term()} | state_timeout.

Event time-out, generic time-out, or state time-out.

The time-out event types that the state machine can generate for itself with the corresponding timeout_action/0s:

In short; the action to set a time-out with EventType is {EventType, Time, ...}.

-type timeout_option() :: {abs, Abs :: boolean()}.

Time-out timer start option, to select absolute time of expiry.

If Abs is true an absolute timer is started, and if it is false a relative, which is the default. See erlang:start_timer/4 for details.

-type timeout_update_action() ::
          {timeout, update, EventContent :: event_content()} |
          {{timeout, Name :: term()}, update, EventContent :: event_content()} |
          {state_timeout, update, EventContent :: event_content()}.

Update the EventContent without affecting the time of expiry.

Sets a new EventContent for a running time-out timer. See timeout_action() for how to start a time-out.

If no time-out of this type is active, instead inserts the time-out event just like when starting a time-out with relative Time = 0. This is a time-out autostart with immediate expiry, so there will be noise for example if a generic time-out name was misspelled.

-type transition_option() ::
          postpone() | hibernate() | event_timeout() | generic_timeout() | state_timeout().

State transition options set by actions.

These determine what happens during the state transition. The state transition takes place when the state callback has processed an event and returns. Here are the sequence of steps for a state transition:

1. All returned actions are processed in order of appearance. In this step all replies generated by any reply_action/0 are sent. Other actions set transition_option/0s that come into play in subsequent steps.

2. If state enter calls are used, it is either the initial state or one of the callback results repeat_state or repeat_state_and_data is used the gen_statem engine calls the current state callback with arguments (enter, State, Data) or (enter, State, State, Data) (depending on callback mode) and when it returns starts again from the top of this sequence.

   If state enter calls are used, and the state changes, the gen_statem engine calls the new state callback with arguments (enter, OldState, Data) or (enter, OldState, State, Data) (depending on callback mode) and when it returns starts again from the top of this sequence.

3. If postpone/0 is true, the current event is postponed.

4. If this is a state change, the queue of incoming events is reset to start with the oldest postponed.

5. All events stored with action/0 next_event are inserted to be processed before previously queued events.

6. Time-out timers event_timeout/0, generic_timeout/0 and state_timeout/0 are handled. Time-outs with zero time are guaranteed to be delivered to the state machine before any external not yet received event so if there is such a time-out requested, the corresponding time-out zero event is enqueued as the newest received event; that is after already queued events such as inserted and postponed events.

   Any event cancels an event_timeout/0 so a zero time event time-out is only generated if the event queue is empty.

   A state change cancels a state_timeout/0 and any new transition option of this type belongs to the new state, that is; a state_timeout/0 applies to the state the state machine enters.

7. If there are enqueued events the state callback for the possibly new state is called with the oldest enqueued event, and we start again from the top of this sequence.

8. Otherwise the gen_statem goes into receive or hibernation (if hibernate/0 is true) to wait for the next message. In hibernation the next non-system event awakens the gen_statem, or rather the next incoming message awakens the gen_statem, but if it is a system event it goes right back into hibernation. When a new message arrives the state callback is called with the corresponding event, and we start again from the top of this sequence.

Note

The behaviour of a zero time-out (a time-out with time 0) differs subtly from Erlang's receive ... after 0 ... end.

The latter receives one message if there is one, while using the timeout_action/0 {timeout, 0} does not receive any external event.

gen_server's time-out works like Erlang's receive ... after 0 ... end, in contrast to gen_statem.